Joe Frikker
95 lines
3.1 KiB
Nix
95 lines
3.1 KiB
Nix
{
|
|
description = "Home Manager configuration of Joe Frikker";
|
|
|
|
inputs = {
|
|
# Specify the source of Home Manager and Nixpkgs.
|
|
nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
|
|
claude-code = {
|
|
url = "github:sadjow/claude-code-nix";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
|
|
home-manager = {
|
|
url = "github:nix-community/home-manager/master";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
# kube = {
|
|
# url = "https://gitea.home-frikker.dedyn.io/jfrikker/kube/archive/1.0.1.tar.gz";
|
|
# inputs.nixpkgs.follows = "nixpkgs";
|
|
# };
|
|
|
|
nix-index-database = {
|
|
url = "github:nix-community/nix-index-database";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
};
|
|
|
|
outputs = { nixpkgs, home-manager, claude-code, nix-index-database, ... }:
|
|
let modules-for-system = pkgs: pkgs.stdenv.mkDerivation {
|
|
name = "home-manager-modules";
|
|
src = pkgs.lib.fileset.toSource {
|
|
root = ./.;
|
|
fileset = pkgs.lib.fileset.unions [
|
|
./home.org
|
|
];
|
|
};
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
${pkgs.emacs}/bin/emacs --batch --eval "(require 'org)" --eval '(org-babel-tangle-file "home.org")'
|
|
runHook postBuild
|
|
'';
|
|
installPhase = ''
|
|
runHook preInstall
|
|
cp -R target $out
|
|
runHook postInstall
|
|
'';
|
|
};
|
|
in {
|
|
homeConfigurations.redbook =
|
|
let pkgs = import nixpkgs { system = "aarch64-darwin"; config.allowUnfree = true; };
|
|
modules = modules-for-system pkgs;
|
|
in home-manager.lib.homeManagerConfiguration {
|
|
inherit pkgs;
|
|
|
|
modules =
|
|
[
|
|
nix-index-database.homeModules.default
|
|
"${modules}/base.nix"
|
|
"${modules}/desktop.nix"
|
|
"${modules}/redbook.nix"
|
|
"${modules}/redbook-desktop.nix"
|
|
] ++
|
|
[{
|
|
home.stateVersion = "22.05";
|
|
home.username = "jfrikker";
|
|
home.homeDirectory = "/Users/jfrikker";
|
|
home.packages = [ pkgs.pinentry_mac ];
|
|
}];
|
|
|
|
extraSpecialArgs = { claude-code = claude-code.packages.aarch64-darwin.default; };
|
|
};
|
|
homeConfigurations.home =
|
|
let pkgs = nixpkgs.legacyPackages.x86_64-linux;
|
|
modules = modules-for-system pkgs;
|
|
in home-manager.lib.homeManagerConfiguration {
|
|
inherit pkgs;
|
|
|
|
modules = [
|
|
nix-index-database.homeModules.default
|
|
] ++
|
|
(pkgs.lib.filter
|
|
(n: pkgs.lib.strings.hasSuffix ".nix" n)
|
|
(pkgs.lib.filesystem.listFilesRecursive "${modules}/base")) ++
|
|
[{
|
|
home.stateVersion = "22.05";
|
|
home.username = "jfrikker";
|
|
home.homeDirectory = "/home/jfrikker";
|
|
}];
|
|
|
|
extraSpecialArgs = { claude-code = claude-code.packages.x86_64-linux.default; };
|
|
};
|
|
packages.aarch64-darwin.default = modules-for-system nixpkgs.legacyPackages.aarch64-darwin;
|
|
};
|
|
}
|